how to generate parts, setting volume and export the parts by using a batch file (or plugin)?

//=============================================================================
//  Export voices as mp3
//  Copyright (2018) msmb
//
//  This program is free software; you can redistribute it and/or modify
//  it under the terms of the GNU General Public License version 2.
//
//  This program is distributed in the hope that it will be useful,
//  but WITHOUT ANY WARRANTY; without even the implied warranty of
//  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
//  GNU General Public License for more details.
//
//  You should have received a copy of the GNU General Public License
//  along with this program; if not, write to the Free Software
//  Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
//=============================================================================
 
import QtQuick 2.0
import MuseScore 1.0
 
MuseScore {
      version:  "0.1"
      description: "This plugin exports all voices in active score as separate mp3 files, volume adjusted to highlight the active voice. Currently path has to be adjusted manually in the plugin's source code."
      menuPath: "Plugins.Export voices as mp3"
 
      onRun: {
        console.log("begin plugin export_voices_mp3");
 
        // --------------------------------------------------------------------
        // configuration section
        // --------------------------------------------------------------------
        var cPath = "c:/temp/";       // including trailing slash - how to get this dynamically? or the current score's path?
        var iVolumeActive = 100;
        var iVolumeBackground = 50;
        // --------------------------------------------------------------------
        // end configuration setting
        // --------------------------------------------------------------------
 
        if(typeof curScore === 'undefined') {
            console.log("no active score found");
        }
        else {
            console.log("current score: ", curScore.name);
 
            var numParts = curScore.parts.length;
            for(var p=0; p < numParts; p++) {
                console.log("working on part ", curScore.parts[p].partName, "...");
                for(var p2=0; p2 < numParts; p2++) {
                    curScore.parts[p2].volume = (p==p2 ? iVolumeActive : iVolumeBackground);
                    // console.log("part '", curScore.parts[p2].partName, "' volume set to ", curScore.parts[p2].volume);
                }
                var cFN = cPath + cleanupFilename(curScore.name) + "-" + cleanupFilename(curScore.parts[p].partName);
                console.log("writing ", cFN, "...");
                writeScore(curScore, cFN, "mp3");
            }
        }
 
        console.log("end plugin export_voices_mp3");
        Qt.quit();
    }
 
    // cleanupFileName
    // remove some special characters not allowed in filenames
    function cleanupFilename(fn) {
        fn = fn.trim()
        fn = fn.replace(/[\n\\\/:\*\?\"<>|]/g,"_")
        return fn
    }
}